home *** CD-ROM | disk | FTP | other *** search
/ FishMarket 1.0 / FishMarket v1.0.iso / fishies / 076-100 / disk_091 / samples / mpu / verbs.adl < prev   
Text File  |  1992-05-06  |  4KB  |  208 lines
  1. VERB
  2.   pry,  strike, wake,   say,
  3.   beam, join,   opener, glow,
  4.   grab, weigh,  rname,  score,
  5.   debug;
  6.  
  7. feel    = touch;
  8. shake    = wake;
  9. hit    = strike;
  10. kill    = strike;
  11. shut    = close;
  12. push    = move;
  13. pull    = move;
  14. lift    = move;
  15. destroy    = break;
  16. incant    = say;
  17. chant    = say;
  18. shout    = say;
  19. yell    = say;
  20. out    = exit;
  21.  
  22.  
  23. cg =
  24.     ($say "You can't go that way.\n")
  25.     ($setg MyLoc ($loc .ME))
  26. ;
  27.  
  28. die =
  29.     ($say "You are dead.  Better luck next time.\n")
  30.     (IF ($not @Wizrd) THEN
  31.      ($spec 3)
  32.     )
  33. ;
  34.  
  35.  
  36.  
  37. Looks =
  38.     (IF ($dobj) THEN
  39.     ($say "Huh?\n")
  40.     ($exit 1)
  41.     )
  42.     ($setg GOVERB TRUE)
  43.     ($setg MyLoc -1)
  44. ;
  45.  
  46. n (PREACT) = Looks;
  47. s (PREACT) = Looks;
  48. e (PREACT) = Looks;
  49. w (PREACT) = Looks;
  50.  
  51. nw(PREACT) = Looks;
  52. ne(PREACT) = Looks;
  53. sw(PREACT) = Looks;
  54. se(PREACT) = Looks;
  55.  
  56. u (PREACT) = Looks;
  57. d (PREACT) = Looks;
  58.  
  59. out (PREACT) = Looks;
  60. enter (PREACT) = Looks;
  61.  
  62. say (PREACT) =
  63.     (Expect ($or NO_OBJ ONE_OBJ STR_OBJ PLAIN_OBJ) NO_OBJ)
  64.     (IF ($not ($dobj)) THEN
  65.     ($say "Type just what you want to say: ")
  66.     ($setg Dobj ($read))
  67.     )
  68.     (IF ($ge ($dobj) 0) THEN
  69.     ($say "You want to make " ($name ($dobj)))
  70.     ($say " a linguistic artifact??  Strange!\n")
  71.     ($exit 1)
  72.     )
  73. ;
  74. say (ACTION) = 
  75.     (IF ($eqst ($dobj) Shazm) THEN
  76.     (WzTgl)
  77.      ELSE
  78.     ($say "Very well.  '")
  79.     ($say ($dobj))
  80.     ($say "'.\n")
  81.     )
  82. ;
  83.  
  84.  
  85. DWIMD =
  86.     ($return (Dwimmer %1))
  87. ;
  88.  
  89. DWIMI =
  90.     ($return (Dwimmer %1))
  91. ;
  92.  
  93.  
  94. wake(PREACT) = Preact;
  95. wake(ACTION) =
  96.     ($say "I don't know how to wake " ($name ($dobj)) ".\n")
  97. ;
  98.  
  99.  
  100. strike(PREACT) = Preact;
  101. strike(ACTION) =
  102.     ($say "Hitting the " ($name ($dobj)) " doesn't seem to do anything.")
  103. ;
  104.  
  105.  
  106. pry(PREACT) =
  107.     (Expect ($or ONE_OBJ PLAIN_OBJ) ($or ONE_OBJ PLAIN_OBJ))
  108.     (CheckAvail)
  109. ;
  110. pry(ACTION) =  ($say "I can't seem to manage that.\n");
  111.  
  112.  
  113. Tress =
  114.     ($say "You were warned about trespassing! The fence is electrified!\n")
  115.     (die)
  116. ;
  117.  
  118.  
  119. score(ACTION) =
  120.     (IF ($eq ($loc .ME) town5) THEN
  121.      ($say
  122. "A mysterious glowing network of lights appears, and you can
  123. just make out the words:
  124.    Your account is now at $" ($str @SCORE) ".
  125.    Thank you for letting Arpa-Citizen's be your host.
  126. The network then disappears.\n"
  127.     )
  128.      ELSE
  129.     ($say "Hmm, you'll have to check at the local bank.\n")
  130.     )
  131. ;
  132.  
  133.  
  134. WizP =
  135.     (IF ($not @Wizrd) THEN
  136.     ($say "Only a real Wizard can do that!\n")
  137.     ($exit 1)
  138.     )
  139. ;
  140.  
  141. rname(PREACT) =
  142.     (IF @Dobj THEN
  143.     (WizP)
  144.     (($sdesc @Dobj))
  145.      ELSE
  146.     (($sdesc ($loc .ME)))
  147.     )
  148.     ($exit 1)
  149. ;
  150. beam(PREACT) = WizP;
  151. grab(PREACT) = WizP;
  152. join(PREACT) = WizP;
  153. opener(PREACT) = WizP;
  154. glow(PREACT) = WizP;
  155. weigh(PREACT) = WizP;
  156. debug(PREACT) = WizP;
  157.  
  158. beam(ACTION) =
  159.     (IF ($dobj) THEN
  160.     ($move .ME ($dobj))
  161.     ($setg MyLoc -1)
  162.     )
  163. ;
  164.  
  165. join(ACTION) =
  166.     (IF ($dobj) THEN
  167.     ($move .ME ($loc ($dobj)))
  168.     ($setg MyLoc -1)
  169.     )
  170. ;
  171.  
  172. opener(ACTION) =
  173.     (IF ($dobj) THEN
  174.     ($setp ($dobj) OPENED TRUE)
  175.     ($say "Opened.\n")
  176.     )
  177. ;
  178.  
  179. glow(ACTION) =
  180.     ($setp .ME LIGHT ($not ($prop .ME LIGHT)))
  181.     (IF ($prop .ME LIGHT) THEN
  182.     ($say "Your body begins to radiate a strong but gentle white light!\n")
  183.      ELSE
  184.     ($say "The light from your body fades away.\n")
  185.     )
  186. ;
  187.  
  188. grab(ACTION) =
  189.     (IF ($dobj) THEN
  190.     ($say "You have the " ($name ($dobj)) ", Boss!\n")
  191.     ($move ($dobj) .ME)
  192.     ($setp .ME HAS ($plus ($prop .ME HAS) ($prop ($dobj) WEIGH)))
  193.     )
  194. ;
  195.  
  196. weigh(ACTION) =
  197.     (IF @Dobj THEN
  198.     ($say "The " ($name @Dobj) " weighs " ($str ($prop @Dobj WEIGH)))
  199.      ELSE
  200.     ($say "You are carrying " ($str ($prop .ME HAS)))
  201.     )
  202.     ($say " pounds, Boss!\n")
  203. ;
  204.  
  205. debug(ACTION) =
  206.     ($spec 1)    { Turn on debugging }
  207. ;
  208.